Squashed 'libs/protobuf/' content from commit fcd3b9a85

git-subtree-dir: libs/protobuf
git-subtree-split: fcd3b9a85ef36e46643dc30176cea1a7ad62e02b

cmake/libprotobuf-lite.cmake

@@ -0,0 +1,36 @@
+# CMake definitions for libprotobuf_lite (the "lite" C++ protobuf runtime).
+
+include(${protobuf_SOURCE_DIR}/src/file_lists.cmake)
+
+add_library(libprotobuf-lite ${protobuf_SHARED_OR_STATIC}
+  ${libprotobuf_lite_srcs}
+  ${libprotobuf_lite_hdrs}
+  ${protobuf_version_rc_file})
+if(protobuf_HAVE_LD_VERSION_SCRIPT)
+  if(${CMAKE_VERSION} VERSION_GREATER 3.13 OR ${CMAKE_VERSION} VERSION_EQUAL 3.13)
+    target_link_options(libprotobuf-lite PRIVATE -Wl,--version-script=${protobuf_SOURCE_DIR}/src/libprotobuf-lite.map)
+  elseif(protobuf_BUILD_SHARED_LIBS)
+    target_link_libraries(libprotobuf-lite PRIVATE -Wl,--version-script=${protobuf_SOURCE_DIR}/src/libprotobuf-lite.map)
+  endif()
+  set_target_properties(libprotobuf-lite PROPERTIES
+    LINK_DEPENDS ${protobuf_SOURCE_DIR}/src/libprotobuf-lite.map)
+endif()
+target_link_libraries(libprotobuf-lite PRIVATE ${CMAKE_THREAD_LIBS_INIT})
+if(protobuf_LINK_LIBATOMIC)
+  target_link_libraries(libprotobuf-lite PRIVATE atomic)
+endif()
+if(${CMAKE_SYSTEM_NAME} STREQUAL "Android")
+  target_link_libraries(libprotobuf-lite PRIVATE log)
+endif()
+target_include_directories(libprotobuf-lite PUBLIC ${protobuf_SOURCE_DIR}/src)
+target_link_libraries(libprotobuf-lite PUBLIC ${protobuf_ABSL_USED_TARGETS})
+if(protobuf_BUILD_SHARED_LIBS)
+  target_compile_definitions(libprotobuf-lite
+    PUBLIC  PROTOBUF_USE_DLLS
+    PRIVATE LIBPROTOBUF_EXPORTS)
+endif()
+set_target_properties(libprotobuf-lite PROPERTIES
+    VERSION ${protobuf_VERSION}
+    OUTPUT_NAME ${LIB_PREFIX}protobuf-lite
+    DEBUG_POSTFIX "${protobuf_DEBUG_POSTFIX}")
+add_library(protobuf::libprotobuf-lite ALIAS libprotobuf-lite)